OpenSCAD - это программа твердотельного 3D моделирования, которая очень популярна среди RepRap сообщества. Принцип ее работы основан на написании алгоритма отрисовки 3D объекта.

Для начала нужно настроить наше рабочее пространство, как это сделать и облегчить себе работу в OpenSCAD читайте здесь.
Теперь удобно расположите ваши руки на клавиатуре и мы начнем.
Весь код мы будем вводить в окне Sublime Text и по нажатию Ctrl+S он будет отображаться в окне OpenSCAD. Но вы также можете обойтись и одним OpenSCAD, в этом случае вводите код в окно редактора OpenSCAD.

Куб и Перемещение

cube(5);

cube(5, center=true);

cube([2,2,5], center=true);

translate([2,2,10]) cube([2,2,5], center=true);

translate([2,2,10]) {
       cube([2,2,5], center=true);
       //......

}

translate([2,-2,-10]) {
       cube([2,2,5], center=true);
       //......
}

Переменные

parameter = 10;

a = 10;
echo(a);

a = 15;
echo(a);

ECHO: 15
ECHO: 15

depth = 2; //глубина модели по оси Y
weight_leg = 2; //ширина ноги по оси X
height_leg = 5; //высота модели по оси Z
legs_space = 5; //расстояние между осями ног по X
weight_bridge = legs_space + weight_leg; //ширина перекладины равна расстоянию между осями ног плюс ширина ноги
height_bridge = weight_leg; //высота перекладины равна ширине ноги

translate([legs_space/2,0,height_leg/2]) //перемещаем правую ногу вправо по X
    cube([weight_leg,depth,height_leg], center=true); //правая нога
translate([-(legs_space/2),0,height_leg/2]) //перемещаем левую ногу влево по X
    cube([weight_leg,depth,height_leg], center=true); //левая нога
translate([0,0,height_leg + height_bridge/2]) //перемещаем перекладину вверх по Z
    cube([weight_bridge,depth,height_bridge], center=true); //перекладина

Сфера

sphere(r=5);

$fn = 50;

sphere(r=5, $fn = 50);

Цилиндр и Вращение

cylinder(r=5, h=5, center=true, $fn = 50);

rotate([0,90,0]) cylinder(r=5, h=5, center=true, $fn = 50);

translate([0,0,5]) rotate([0,90,0]) cylinder(r=5, h=5, center=true, $fn = 50);

translate([0,0,5]) {
    rotate([0,90,0]){
        cylinder(r=5, h=5, center=true, $fn = 50);
    }
}

cylinder(r1=20, r2=3, h=40, center=true, $fn=50);

Объединение и Вырезание

union() {
    cylinder (h = 4, r=1, center = true, $fn=100);
    rotate ([90,0,0]) cylinder (h = 4, r=0.9, center = true, $fn=100);
}

$fn = 50;

difference() {
    // Из этого цилиндра мы будем вырезать
    cylinder(r=10, h=5, center=true);

    // Все остальное следующее далее будет вырезано
    cylinder(r=8, h=6, center=true);
}

$fn = 50;

difference() {
    // Эта часть будет создана
    cylinder(r=10, h=5, center=true);

    // Все остальное следующее далее будет вырезано
    #cylinder(r=8, h=6, center=true);
}

difference() {
    union() {
        cylinder (h = 4, r=1, center = true, $fn=100);
        rotate ([90,0,0]) cylinder (h = 4, r=0.9, center = true, $fn=100);
    }
    rotate([0,90,0]) cylinder(r=1, h=10, center=true, $fn=100);
}

Модули

// Инструкции как должна создаваться буква "П"
module pi() {
    // Параметры
    depth = 2; //глубина модели по оси Y
    weight_leg = 2; //ширина ноги по оси X
    height_leg = 5; //высота модели по оси Z
    legs_space = 5; //расстояние между осями ног по X
    weight_bridge = legs_space + weight_leg; //ширина перекладины равна расстоянию между осями ног плюс ширина ноги
    height_bridge = weight_leg; //высота перекладины равна ширине ноги

    translate([legs_space/2,0,height_leg/2]) //перемещаем правую ногу вправо по X
        cube([weight_leg,depth,height_leg], center=true); //правая нога
    translate([-(legs_space/2),0,height_leg/2]) //перемещаем левую ногу влево по X
        cube([weight_leg,depth,height_leg], center=true); //левая нога
    translate([0,0,height_leg + height_bridge/2]) //перемещаем перекладину вверх по Z
        cube([weight_bridge,depth,height_bridge], center=true); //перекладина
}

// Эта строчка говорит OpenSCAD найти инструкции как создавать букву "П" и создать ее
pi();

// Инструкции как должна создаваться буква "П"
module pi(depth, weight_leg, height_leg, legs_space) {
    // Параметры
    weight_bridge = legs_space + weight_leg; //ширина перекладины равна расстоянию между осями ног плюс ширина ноги
    height_bridge = weight_leg; //высота перекладины равна ширине ноги

    translate([legs_space/2,0,height_leg/2]) //перемещаем правую ногу вправо по X
        cube([weight_leg,depth,height_leg], center=true); //правая нога
    translate([-(legs_space/2),0,height_leg/2]) //перемещаем левую ногу влево по X
        cube([weight_leg,depth,height_leg], center=true); //левая нога
    translate([0,0,height_leg + height_bridge/2]) //перемещаем перекладину вверх по Z
        cube([weight_bridge,depth,height_bridge], center=true); //перекладина
}

// Эта строчка говорит OpenSCAD найти инструкции как создавать букву "П" и создать ее
pi(2,2,5,5);
translate([10,0,0]) pi(1,3,7,4);
translate([-10,0,0]) pi(4,1,2,5);

OpenSCAD это бесплатное программное обеспечение (ПО) для создания твердотельных 3D CAD моделей. Это ПО доступно для разных операционных систем, таких как Linux/UNIX, Windows и Mac OS X.
К сожалению большинство бесплатного ПО для 3D моделирования сфокусировано на артистических аспектах, а не на CAD моделировании. OpenSCAD применяют для разработки деталей машин, если вы планируете разрабатывать 3D анимацию, то это ПО не для вас. Поэтому его очень любят RepRap разработчики и простые инженеры. Большинство проектов RepRap сделано именно в OpenSCAD.

Настройка

1. Скачать пакет настройки Sublime Text для OpenSCAD (OpenSCAD_Sublime.zip).
2. Запускаем Sublime Text  и определяем каталог где находятся пакеты настроек, меню Preferences - Browse Packages... (запоминаем этот каталог).
3. Копируем папку OpenSCAD из архива OpenSCAD_Sublime.zip в каталог определенный в пункте 2.
4. Запускаем OpenSCAD включаем настройку в меню Design - Automatic Reload and Compile и прячем редактор в меню View - Hide editor так как мы будем использовать внешний редактор.
5. Еще один маленький твик (возможно кому-то поможет),если нет ошибок в скрипте но ваша модель не отображается, то увеличьте лимит отображаемых элементов в Edit - Preferences - Advanced - Turn off rendering at ... elements.